If the LOG window has been suppressed, it can be difficult for the user to know how whether anything is happening.

The following code can be used to generate a 'processing' window while the remote code is running, which then closes once processing is complete.

The code makes use of asynchronous processing allowing the rsubmit block to process in the background, while playing the 'animated' progress window in the foreground on the local machine.  It also makes use of the ability to pass a macro variable from the remote session to the local session, providing the trigger to stop the 'animation'.

The drawback to this process is that the packet passed from the remote processing will wait before updating the local macro variable if the local machine is busy. To allow time for the update, the local process uses the SLEEP function to add a millisecond delay to the animation.

* Set option for Remote session to run asynchronously ;
* Set options for Remote Macro to synchronize on execution ;
* instead of at synchronization point ;
 
options noconnectwait sysrputsync ;
 
* Initialize macro variable on local session ;
%let rsub = 0 ;
 
* Connect to remote session ;
signon rmt sascmd="!sascmd" ;
 
rsubmit ;
 
* Do some processing - slowly! ;
  data temp ;
    do i = 1 to 100 ;
      x = ranuni(0) ;
   wait = sleep(5,.01) ;
      output ;
    end ;
  run ;
 
* Pass macro variable from remote session to local session ;
  %sysrput rsub = 1 ;
 
endrsubmit ;
 
* Define 'Please Wait' window ;
 
data _null_ ;
  window status
    group = static
    #8 @12 "Remote Submit Progress Window" persist = yes
    #12 @12 "Report running: Please wait" persist = yes
    
    group = progressbar
    #12 @(41 + progress) " » » » » » » » » » "
    ; 
 
 display status.static noinput ;
 
 do until(input(symget('rsub'),1.)) ;
   do loop1 = 1 to 10 ;
     progress + 0.15 ;
     display status.progressbar noinput ;
* Need to pause the progress bar to allow the remote macro to update the local macro ;
     paused = sleep(1,.001) ;
   end ;
   progress = 0 ;
 end ;
run ;
 
signoff ;

An alternative is to capture the macro variable on the local session, then use the %SYSLPUT statement to transfer the macro variable from the local environment to the remote environment..

The following code gives a general example, capturing a date-string and passing to a remote session:

 
%window passit
    #6  @12 "Enter a date (e.g. 18JUL2008)"
        @44 datevar 9 attr  = underline
                      color = green 
    #8  @12 "(If no date is specified today's date will be used.)" 
            color = gray
    #12 @12 "Make your selection, then press ENTER to continue" 
;

/* Check entered value - if nothing entered, or incorrect date       */
/* then return current date                                          */

%macro validdt ;
  %global datevar ;
  %let datevar= ; 
  %display passit blank ; 
  %if &datevar = %then %let datevar = &sysdate9 ;
  %else 
  %do ;
    options nonotes ;
    data _null_ ;
	  if input("&datevar",date9.) = . then
	  do ;
	    _error_ = 0 ;
        call symput("datevar","&sysdate9") ;
	  end ;
	run ;
	options notes ; 
  %end ;
%mend validdt ;

%validdt

options /*Specify site-specific options to establish remote session  */ ;

signon ;

/* Having established the remote connection, pass the Macro Variable */
/* created in the local session to the remote session                */

%syslput datevar = &datevar ;

rsubmit ;

%put _user_ ;

/* Any other code on remote session here */

endrsubmit ;

signoff ;

The %SYSRPUT statement can be used to transfer a macro variable from the remote session to the local session.

To over-ride the default font and font-size in the LOG and OUTPUT windows, try issuing the following OPTIONS statement:

OPTIONS font= "courier" 16;

Which changes the font to Courier and the point-size to 16. It is also possible to add keywords for BOLD | NORMAL and REGULAR | ITALIC .

OPTIONS font=<font-name> <BOLD|NORMAL> <REGULAR|ITALIC> <font-size> ;

Top Tip: Stick with monospace fonts!
Proportional fonts can give some odd results, and cause a warning message in the log. (The developers at Newtyne Towers don't like warning messages in the log!)

In Excel, the PMT function returns the payment amount for a loan based on an interest rate and a constant payment schedule:

If the Type parameter is omitted, the PMT function assumes a Type value of 0.

e.g. The monthly payment on a £5,000 loan at an annual rate of 7.5%. The loan is paid off in 2 years (ie: 2 x 12). All payments are made at the beginning of the period.

e.g. An amount of £50,000 is borrowed for 30 years at an annual interest rate of 10 percent compounded monthly. The monthly payment can be expressed as: